
# Section mechanism¶

Sections are naming scopes that permit creating section-local declarations that can be used by other declarations in the section. Declarations made with Variable, Hypothesis, Context, Let, Let Fixpoint and Let CoFixpoint (or the plural variants of the first two) within sections are local to the section.

In proofs done within the section, section-local declarations are included in the local context of the initial goal of the proof. They are also accessible in definitions made with the Definition command.

Sections are opened by the Section command, and closed by End. Sections can be nested. When a section is closed, its local declarations are no longer available. Global declarations that refer to them will be adjusted so they're still usable outside the section as shown in this example.

Command Section ident

Opens the section named ident. Section names do not need to be unique.

Command End ident

Closes the section or module named ident. See Terminating an interactive module or module type definition for a description of its use with modules.

After closing the section, the local declarations (variables and local definitions, see Variable) are discharged, meaning that they stop being visible and that all global objects defined in the section are generalized with respect to the variables and local definitions they each depended on in the section.

Error There is nothing to end.
Error Last block to end has name ident.

Note

Most commands, such as the Hint commands, Notation and option management commands that appear inside a section are canceled when the section is closed.

Command Let ident_decl def_body
Command Let Fixpoint fix_definition with fix_definition*
Command Let CoFixpoint cofix_definition with cofix_definition*

These are similar to Definition, Fixpoint and CoFixpoint, except that the declared constant is local to the current section. When the section is closed, all persistent definitions and theorems within it that depend on the constant will be wrapped with a term_let with the same declaration.

As for Definition, Fixpoint and CoFixpoint, if term is omitted, type is required and Coq enters proof mode. This can be used to define a term incrementally, in particular by relying on the refine tactic. In this case, the proof should be terminated with Defined in order to define a constant for which the computational behavior is relevant. See Entering and exiting proof mode.

Command Context binder+

Declare variables in the context of the current section, like Variable, but also allowing implicit variables, Implicit generalization, and let-binders.

Context {A : Type} (a b : A). Context {EqDec A}. Context (b' := b).

Section Binders. Section Sections and contexts in chapter Typeclasses.

Example: Section-local declarations

Section s1.
Variables x y : nat.
x is declared y is declared

The command Let introduces section-wide Let-in definitions. These definitions won't persist when the section is closed, and all persistent definitions which depend on y' will be prefixed with let y' := y in.

Let y' := y.
y' is defined
Definition x' := S x.
x' is defined
Definition x'' := x' + y'.
x'' is defined
Print x'.
x' = S x : nat
Print x''.
x'' = x' + y' : nat
End s1.
Print x'.
x' = fun x : nat => S x : nat -> nat Arguments x' x%nat_scope
Print x''.
x'' = fun x y : nat => let y' := y in x' x + y' : nat -> nat -> nat Arguments x'' (x y)%nat_scope

Notice the difference between the value of x' and x'' inside section s1` and outside.